Anillo 3 - Original
An interactive fiction by Mel Hython (2009) - the Inform 7 source text
Contents
Previous
Next
Complete text
Chapter 1 - El inicio
NoLugar is a room.
[--------------------------------------------------
Regla activada al iniciar el juego
--------------------------------------------------]
[ Un poco de decoracion ]
To say hambre y sed:
if hambre del jugador is greater than 130:
say "H";
otherwise:
say "-";
if sed del jugador is greater than 160:
say "S";
otherwise:
say "-".
To decide which number is nneg of (num - a number):
if num is greater than 0:
decide on num;
otherwise:
decide on 0.
[ Localidades 'especiales' ]
To say nombre localidad:
if map region of location is nothing:
say location;
otherwise if location is Pantano1:
say "Manantial";
otherwise if location is Pantano26:
say "Huerta";
otherwise if location is Pantano23:
say "Hiedra y montículo";
otherwise if location is Pantano28:
say "Entrada a cuevas";
otherwise if location is Lava:
say "Río de lava";
otherwise if location is Pantano12:
say "Arenas movedizas";
otherwise if location is Pantano17:
say "Viejas ruinas";
otherwise if location is PuertaCastillo:
say "Camino de la fortaleza";
otherwise:
say map region of location.
[No me gusta nada el status estandar, veamos si hago algo mejor]
[De la mano de Eliuk]
To close the statusline:
(- if (gg_statuswin)
{ glk_window_set_arrangement(glk_window_get_parent(gg_statuswin),winmethod_Fixed+winmethod_Above,0,0); } -)
To open the statusline:
(- if (gg_statuswin)
{ glk_window_set_arrangement(glk_window_get_parent(gg_statuswin),winmethod_Fixed+winmethod_Above,1,0); } -)
When play begins:
enable veneer acceleration;
close the statusline;
poner cuadro de inicio;
wait for any key;
now the player is in NoLugar;
now the player is nuhur;
clear the screen;
poner cuadro de creditos;
wait for any key;
clear the screen;
say line break;
say line break;
assign the sound of inicio to channel 0 with 100% volume; [and 1 repetitions];
assign the sound of cuevas to channel 1 with 40% volume, endless loop;
assign the sound of pantano to channel 2 with 40% volume, endless loop;
assign the sound of castillo to channel 3 with 85% volume, endless loop;
assign the sound of final to channel 4 with 100% volume, endless loop;
assign the sound of efectos to channel 5 with 70% volume, endless loop;
start musical introduction;
poner cuadro de aviso;
wait for any key;
clear the screen;
say line break;
say line break;
contar inicio de la historia;
say line break;
say line break;
open the statusline;
change left hand status line to "[nombre localidad]";
change right hand status line to "[el portador]: [hambre y sed]";
now Efectos-Sonando is true;
dplay sound of efectos;
activar sonidos ambientales.
[change the volume of the sound of inicio to 40%.]
[ QQQ: Para las pruebas de la parte final
move player to Lava;
move pergamino azulado to player;
move cuenta to player;
move dedal to player;
now cuenta is lit.]
[FRASE: Cuadro de inicio con el nombre del relato y fecha]
To poner cuadro de inicio:
display the boxed quotation
"
Anillo III - Diseño original
Un relato de Mel Hython.
Año 2009, sobre diseño de 1989.
";
show the current quotation.
To poner cuadro de aviso:
display the boxed quotation
"
Este relato interactivo cuenta con efectos sonoros
de ambientación y con música.
Para activar o desactivar la música
teclea simplemente 'MUSICA'.
Para activar o desactivar los efectos sonoros
teclea simplemente 'EFECTOS'.
";
show the current quotation.
To poner cuadro de creditos:
display the boxed quotation
"
Portada de: Urbatain.
Sonidos del pantano de: Xpktro.
Librería de sonidos: Eliuk Blau.
Musica de: coax, the ice garden
";
show the current quotation.
[COMANDO: Introducción que relata]
To contar inicio de la historia:
relatar fragmento en Table of Historia Inicial, limpiando pantalla.
[HISTORIA: El fragmento inicial]
Table of Historia Inicial
| frase |
| "Demasiado ha durado ya tu maldición. Pero pronto cesará." |
| "El sucio El Nigróh, que debería haber estado muerto, redujo tu magnificiencia, tu poder, tu destino, el legado de todos tus ancestros, por no hablar de la belleza de un auténtico dragón, a una caricatura." |
| "Un ridículo anillo de ojos de esmeralda." |
| "A duras penas lograste escapar de aquel pueblo minúsculo en el que casi todos te odiaban, y con gran dificultad lograste que un humano muy corto de miras te sacase del castillo del noble local. Mucho habéis sufrido tú y el humano desde entonces pero todo está a punto de acabarse." |
| "Ahora dominas al humano por completo, como si fuese una de tus añoradas alas, y estáis casi junto a las puertas del nigromante Sady Omú, el único con el poder y, tal vez, la voluntad de retornarte tu cuerpo de dragón." |
| "Aquí, entre árboles, rodeados de apestosos pantanos, en unos de los dedos de tu portador, mirando por sus ojos, puedes adivinar la silueta de la fortaleza del nigromante al noreste. Ya falta poco." |
| "Mas, es probable que esos lugares estén vigilados por las tropas de orcos del nigromante, tropas estúpidas, que serían incapaces de reconocer en ti el poder, la majestad de un auténtico dragón. Hay que evitarlas." |
| "De forma que entrar por la puerta principal queda descartado, pero has podido averiguar que hay otra forma de llegar, por los sótanos de la fortaleza, desde alguna entrada que parece existir en alguna parte de los laberínticos pantanos. Tal vez hacia el sureste desde aquí." |